home *** CD-ROM | disk | FTP | other *** search
/ Wonky Flux Batch 2019 02 / Wonky_Flux_Batch_2019-02.zip / Wonky Flux Batch 2019-02 / 023 - Big U Macroworks.dsk / INPUT.SETUP.bas < prev    next >
BASIC Source File  |  2019-02-16  |  3KB  |  54 lines
  1. 1  ONERR  GOTO 520
  2. 2 D$ =  CHR$(4):KP = 49152:KR = 49168:Q$ =  CHR$(34):CS =  -958:CL =  -868:BP$ =  CHR$(7):MA = 16640 +7:DE = MA +1
  3. 10  TEXT : HOME : NORMAL : PRINT  CHR$(21)
  4. 20  PRINT "INPUT.40 & INPUT.80"
  5. 30  PRINT "SETUP PROGRAM"
  6. 40  PRINT "-------------": PRINT 
  7. 50  PRINT "COPYRIGHT (C) 1985, RANDY BRANDT"
  8. 60  PRINT "BEAGLE BROS MICRO SOFTWARE, INC."
  9. 70  VTAB 8: PRINT : CALL CS: PRINT "SET UP WHICH PROGRAM?": PRINT : PRINT "F - INPUT.40": PRINT : PRINT "E - INPUT.80": PRINT : PRINT "Q - QUIT": PRINT 
  10. 74  PRINT "PRESS "Q$"F"Q$", "Q$"E"Q$", OR "Q$"Q"Q$": ";
  11. 90  GET X$: IF X$ = "Q"  OR X$ = "q"  THEN 550
  12. 100 IN$ = "INPUT.40": IF X$ = "E"  OR X$ = "e"  THEN IN$ = "INPUT.80": GOTO 130
  13. 110  IF X$ < >"F"  AND X$ < >"f"  THEN  PRINT BP$;: GOTO 90: REM <CTRL-M><CTRL-M>40<CTRL-J>
  14. 130  VTAB 8: PRINT : CALL CS: PRINT "LOADING "IN$
  15. 140  PRINT D$"BLOAD"IN$:LE =  PEEK(48857) +256 * PEEK(48858)
  16. 150  GOSUB 500: REM   LENGTH INFO
  17. 160  GET X$: IF X$ =  CHR$(27)  THEN 70
  18. 170  IF X$ = "U"  OR X$ = "u"  THEN SL =  PEEK(MA): GOTO 250
  19. 180  IF X$ < >"C"  AND X$ < >"c"  THEN  PRINT BP$;: GOTO 160
  20. 190  VTAB 18: PRINT : CALL CS
  21. 200  VTAB 18: PRINT "ENTER NEW MAXIMUM LENGTH";: INPUT ": ";SL$: IF SL$ = ""  THEN 150
  22. 210 SL =  VAL(SL$)
  23. 220  IF SL <1  OR SL >255  THEN  PRINT BP$;: GOTO 200
  24. 240  POKE MA,SL: REM <CTRL-M><CTRL-M>
  25. 250  GOSUB 450
  26. 260  GET X$: IF X$ =  CHR$(27)  THEN 150
  27. 270  IF X$ = "U"  OR X$ = "u"  THEN 310
  28. 280  IF X$ < >"K"  AND X$ < >"k"  THEN  PRINT BP$;: GOTO 260
  29. 290  VTAB 12: PRINT : CALL CS: PRINT "PRESS NEW DELETE KEY: ";: GET DK$: IF DK$ =  CHR$(27)  THEN 250
  30. 300 DK =  ASC(DK$) +128
  31. 310  POKE DE,DK
  32. 320  VTAB 8: PRINT : CALL CS: PRINT "NEW "IN$" SETUP:": PRINT : PRINT "MAXIMUM LENGTH: ";: INVERSE : PRINT SL: NORMAL 
  33. 330  PRINT "DELETE KEY: ";: INVERSE : IF DK = 255  THEN  PRINT "DELETE KEY": GOTO 360
  34. 340  IF DK <160  THEN  PRINT "CONTROL-"; CHR$(DK +64): GOTO 360
  35. 350  PRINT  CHR$(DK)
  36. 360  NORMAL : PRINT : PRINT "PRESS RETURN TO SAVE "IN$",": PRINT "OR PRESS ESCAPE TO REDO: ";
  37. 370  GET X$: IF X$ =  CHR$(27)  THEN 150
  38. 375  IF X$ < > CHR$(13)  THEN 370
  39. 380  VTAB  PEEK(37): HTAB 1: PRINT "SAVING CONFIGURED VERSION...";: CALL CS: PRINT 
  40. 390  PRINT D$"UNLOCK"IN$
  41. 391  PRINT D$"BSAVE"IN$",A$4000,L"LE: GOTO 70
  42. 450  VTAB 8: PRINT : CALL CS: PRINT "CURRENT DELETE KEY: ";:DK =  PEEK(DE): IF DK <160  THEN  PRINT "CONTROL-"; CHR$(DK +64): GOTO 480
  43. 460  IF DK = 255  THEN  PRINT "DELETE KEY": GOTO 480
  44. 470  PRINT  CHR$(DK)
  45. 480  PRINT : PRINT "K - SELECT A NEW KEY": PRINT 
  46. 490  PRINT "U - USE EXISTING KEY": PRINT : PRINT "PRESS "Q$"K"Q$" OR "Q$"U"Q$": ";: RETURN 
  47. 500  VTAB 8: PRINT : CALL CS: PRINT "CURRENT MAXIMUM ENTRY LENGTH: ";:SL =  PEEK(MA): PRINT SL
  48. 510  PRINT : PRINT "U - USE "SL" FOR MAXIMUM LENGTH": PRINT : PRINT "C - CHANGE MAXIMUM LENGTH": PRINT : PRINT "PRESS "Q$"U"Q$" OR "Q$"C"Q$": ";: RETURN 
  49. 520 ER =  PEEK(222):EL =  PEEK(218) + PEEK(219) *256
  50. 530  IF EL = 140  THEN  VTAB 8: PRINT : PRINT BP$;"CAN'T FIND "IN$: PRINT : PRINT "PLEASE INSERT BIG.U": PRINT "AND PRESS A KEY ";: GET X$: ON X$ < > CHR$(27) GOTO 140: GOTO 550
  51. 535  IF EL = 390  THEN 391
  52. 540  IF EL = 391  THEN  VTAB 13: PRINT BP$: CALL CS: PRINT "DISK ERROR": PRINT "PRESS RETURN TO TRY AGAIN": PRINT "OR PRESS ESCAPE: ";: GET X$: ON X$ < > CHR$(27) GOTO 391: GOTO 150
  53. 545  POKE 216,0: RESUME 
  54. 550  HOME : PRINT : PRINT "TYPE "Q$"RUN"Q$" TO RESTART."